boxxy/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2
   3 pkgname=boxxy
   4 pkgver=0.7.1
   5 pkgrel=1
   6 pkgdesc="Put bad Linux applications in a box with only their files"
   7 arch=('x86_64')
   8 url="https://github.com/queer/boxxy"
   9 license=('MIT')
  10 depends=('gcc-libs')
  11 makedepends=('cargo')
  12 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
  13 sha256sums=('a23ef96a981254f6ee35936456bfd4c923aa32bff87bc7b2f56ef0dff0f745af')
  14 options=('!lto')
  15
  16 prepare() {
  17   cd "$pkgname-$pkgver"
  18   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  19 }
  20
  21 build() {
  22   cd "$pkgname-$pkgver"
  23   cargo build --release --frozen
  24 }
  25
  26 check() {
  27   cd "$pkgname-$pkgver"
  28   cargo test --frozen
  29 }
  30
  31 package() {
  32   cd "$pkgname-$pkgver"
  33   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  34   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  35   install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  36 }
  37
  38 # vim: ts=2 sw=2 et: