bpython/trunk/PKGBUILD

   1 # Maintainer: Kyle Keen < keenerd at gmail >
   2 # Contributor: Thomas Dziedzic < gostrc at gmail >
   3 # Contributor: Mike Sampson <mike at sambodata dot com>
   4 # Contributor: Anton Bazhenov <anton.bazhenov at gmail>
   5
   6 pkgname=bpython
   7 pkgver=0.24
   8 pkgrel=3
   9 pkgdesc='Fancy ncurses interface to the Python interpreter'
  10 arch=('any')
  11 url='https://bpython-interpreter.org/'
  12 license=('MIT')
  13 depends=('python-pygments' 'python-requests' 'python-curtsies' 'python-greenlet'
  14          'python-typing_extensions' 'python-pyxdg')
  15 optdepends=('python-urwid: for bpython-urwid'
  16             'python-jedi: multiline completion'
  17             'python-watchdog: module reloading')
  18 makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
  19 checkdepends=('python-pytest')
  20 #source=(https://bpython-interpreter.org/releases/bpython-${pkgver}.tar.gz)  # slow
  21 #source=("https://github.com/bpython/bpython/archive/$pkgver-release.tar.gz")  # missing version data
  22 source=("https://files.pythonhosted.org/packages/source/b/bpython/bpython-$pkgver.tar.gz")
  23 sha256sums=('98736ffd7a8c48fd2bfb53d898a475f4241bde0b672125706af04d9d08fd3dbd')
  24
  25 build() {
  26   cd bpython-$pkgver
  27   python -m build --wheel --no-isolation
  28 }
  29
  30 check() {
  31   cd bpython-$pkgver
  32   pytest --deselect bpython/test/test_interpreter.py::TestInterpreter::test_syntaxerror
  33 }
  34
  35 package() {
  36   cd bpython-$pkgver
  37
  38   python -m installer --destdir="$pkgdir" dist/*.whl
  39   install -Dm644 LICENSE "$pkgdir/usr/share/licenses/bpython/LICENSE"
  40 }