budgie-extras/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
   2 # Contributor: Campbell Jones <arch at serebit dot com>
   3
   4 pkgname=budgie-extras
   5 pkgver=1.5.0
   6 pkgrel=1
   7 pkgdesc='Additional Budgie Desktop components from the Ubuntu Budgie team'
   8 arch=('x86_64')
   9 license=('GPL3')
  10 url='https://github.com/UbuntuBudgie/budgie-extras'
  11 depends=('budgie-desktop' 'wmctrl' 'xdotool' 'xprintidle' 'python' 'python-gobject' 'python-cairo' 'libgee'
  12          'zenity' 'vorbis-tools' 'python-psutil' 'sound-theme-freedesktop' 'imagemagick' 'python-pillow'
  13          'python-svgwrite' 'python-cairosvg' 'python-pyudev' 'python-requests' 'libpeas' 'json-glib'
  14          'libkeybinder3' 'python-pyperclip' 'python-xlib' 'xorg-xinput' 'granite' 'appstream'
  15          'libnma' 'libhandy0' 'xorg-xprop')
  16 makedepends=('gobject-introspection' 'meson' 'ninja' 'vala' 'intltool' 'git')
  17 source=("git+$url.git#tag=v$pkgver"
  18         "git+https://github.com/UbuntuBudgie/QuickChar.git"
  19         "git+https://github.com/UbuntuBudgie/applications-menu.git"
  20         "git+https://github.com/UbuntuBudgie/budgie-network-applet.git"
  21         "git+https://github.com/UbuntuBudgie/budgie-trash-applet.git")
  22 sha512sums=('SKIP'
  23             'SKIP'
  24             'SKIP'
  25             'SKIP'
  26             'SKIP')
  27
  28 prepare() {
  29   cd "$pkgname"
  30
  31   git submodule init
  32   git config submodule.budgie-quickchar/quickchar.url ../QuickChar
  33   git config submodule.budgie-applications-menu/applications-menu.url ../applications-menu
  34   git config submodule.budgie-network-manager/budgie-network-applet.url ../budgie-network-applet
  35   git config submodule.budgie-trash/trash.url ../budgie-trash-applet
  36   git -c protocol.file.allow=always submodule update
  37 }
  38
  39 build() {
  40   arch-meson "$pkgname" build -D b_pie=false
  41   meson compile -C build
  42 }
  43
  44 package() {
  45   meson install -C build --destdir "$pkgdir"
  46 }