byobu/trunk/PKGBUILD

   1 # Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
   2 # Contributor: Daniel Landau <aur@landau.fi>
   3 # Contributor: Justin Coffman <jcoffman at datasecu dot red>
   4 # Contributor: Sibren Vasse <arch at sibrenvasse dot nl>
   5 # Contributor: oozyslug <oozyslug at gmail dot com>
   6 # Contributor: Justin Coffman <jcoffman at datasecu dot red>
   7
   8 pkgname=byobu
   9 pkgver=5.133
  10 pkgrel=3
  11 pkgdesc='Enhanced tmux'
  12 arch=(any)
  13 url='https://byobu.org/'
  14 license=(GPL3)
  15 depends=(libnewt python tmux)
  16 makedepends=(gettext setconf)
  17 source=("$pkgname-$pkgver.tar.gz::https://launchpad.net/byobu/trunk/$pkgver/+download/byobu_$pkgver.orig.tar.gz"
  18         "$pkgname-$pkgver.tar.gz.asc::https://launchpad.net/byobu/trunk/$pkgver/+download/..-byobu_$pkgver.orig.tar.gz.asc")
  19 sha256sums=('4d8ea48f8c059e56f7174df89b04a08c32286bae5a21562c5c6f61be6dab7563'
  20             'SKIP')
  21 validpgpkeys=('E2D9E1C5F9F5D59291F4607D95E64373F1529469') # Dustin Kirkland <kirkland@ubuntu.com>
  22
  23 prepare() {
  24   # Adjust path to SOCKETDIR
  25   setconf "$pkgname-$pkgver/etc/byobu/socketdir" SOCKETDIR '"/tmp/screens"'
  26
  27   # Tweak the two .desktop files that comes with Byobu
  28   cd "$pkgname-$pkgver/usr/share/byobu/desktop"
  29   setconf byobu.desktop Name 'Byobu Gnome Terminal'
  30   setconf byobu.desktop Icon=/usr/share/byobu/pixmaps/byobu.svg
  31   setconf byobu.desktop \
  32     Exec "gnome-terminal --name=us.kirkland.terminals.byobu --class=us.kirkland.terminals.byobu -- byobu"
  33   setconf byobu.desktop.old Icon=/usr/share/byobu/pixmaps/byobu.svg
  34 }
  35
  36 build() {
  37   cd "$pkgname-$pkgver"
  38   ./configure --prefix=/usr --sysconfdir=/etc
  39   make
  40 }
  41
  42 package() {
  43   DESTDIR="$pkgdir" make -C "$pkgname-$pkgver" install
  44
  45   # Move .desktop files to /usr/share/applications
  46   install -d "$pkgdir/usr/share/applications"
  47   mv "$pkgdir/usr/share/byobu/desktop/byobu.desktop" \
  48     "$pkgdir/usr/share/applications/byobu.desktop"
  49   mv "$pkgdir/usr/share/byobu/desktop/byobu.desktop.old" \
  50     "$pkgdir/usr/share/applications/byobu_old.desktop"
  51   rmdir "$pkgdir/usr/share/byobu/desktop"
  52 }
  53
  54 # getver: launchpad.net/byobu/+download
  55 # vim: ts=2 sw=2 et: