cairo-dock-plug-ins/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Tofe <chris.chapuis@gmail.com>
   3 # Contributor: zhuqin <zhuqin83@gmail.com>
   4 # Contributor: tri1976 <trile7@gmail.com>
   5 # Contributor: snoopy33 <snoopy33@no-log.org>
   6
   7 pkgname=cairo-dock-plug-ins
   8 pkgver=3.4.1
   9 pkgrel=20
  10 pkgdesc='Plugins for Cairo-Dock'
  11 arch=('x86_64')
  12 url='https://glx-dock.org'
  13 license=('GPL')
  14 depends=('cairo-dock')
  15 makedepends=('alsa-lib' 'cmake' 'dbus-sharp-glib' 'fftw' 'gnome-menus'
  16              'gtk-sharp-3' 'gvfs' 'libetpan' 'libexif' 'libical' 'libpulse'
  17              'libxklavier' 'lm_sensors' 'python' 'ruby' 'upower'
  18              'vala' 'vte3' 'zeitgeist')
  19 optdepends=('alsa-lib: Sound Control, Sound Effects applets'
  20             'dbus-sharp-glib: Mono API'
  21             'fftw: Impulse applet'
  22             'gnome-menus: Applications Menu applet'
  23             'gtk-sharp-3: Mono API'
  24             'gvfs: GVFS integration'
  25             'libetpan: Mail applet'
  26             'libexif: Slider applet'
  27             'libical: Clock applet'
  28             'libpulse: Impulse applet'
  29             'libxklavier: Keyboard Indicator applet'
  30             'lm_sensors: System Monitor applet'
  31             'python: Python 3 API'
  32             'ruby: Ruby API'
  33             'upower: Power Manager applet'
  34             'vte3: Terminal applet'
  35             'wireless_tools: Wifi applet'
  36             'zeitgeist: Recent Events applet')
  37 replaces=('cairo-dock-plugins')
  38 source=("cairo-dock-plug-ins-${pkgver}.tar.gz::https://github.com/Cairo-Dock/cairo-dock-plug-ins/archive/${pkgver}.tar.gz"
  39         'cairo-dock-plug-ins-mono.patch'
  40         cairo-dock-plugins-3.4.1-gcc10-extern.patch
  41         cairo-dock-plugins-3.4.1-time_h-confict.patch)
  42 sha256sums=('321113fb8fa214d965c9827b82890651dc4cd0beb23aef0e2d3f5caf806ebdc2'
  43             '061115f3638c47eab04d48808d4cc61e294877643a61c82061d7af2523b4f724'
  44             '38311d5f109ba2e290c0d300e27ed2da06e408bde480d81727a42521bd5052c5'
  45             'f5b859f9acd069cadcfc6188fa1551aa25053abaddf3aa1041cdf10cab3a8fa5')
  46
  47 prepare() {
  48   cd cairo-dock-plug-ins-${pkgver}
  49
  50   patch -Np1 -i ../cairo-dock-plug-ins-mono.patch
  51   patch -Np1 -i ../cairo-dock-plugins-3.4.1-gcc10-extern.patch
  52   patch -Np1 -i ../cairo-dock-plugins-3.4.1-time_h-confict.patch
  53   sed 's/gmcs/mcs/' -i CMakeLists.txt
  54
  55   if [[ -d build ]]; then
  56     rm -rf build
  57   fi
  58   mkdir build
  59 }
  60
  61 build() {
  62   cd cairo-dock-plug-ins-${pkgver}/build
  63
  64   cmake .. \
  65     -DCMAKE_BUILD_TYPE='Release' \
  66     -DCMAKE_INSTALL_PREFIX='/usr'
  67   make
  68 }
  69
  70 package() {
  71   cd cairo-dock-plug-ins-${pkgver}/build
  72
  73   make DESTDIR="${pkgdir}" install
  74   mv "${pkgdir}"/usr/lib/{cli,mono}
  75 }
  76
  77 # vim: ts=2 sw=2 et: