cairo-dock/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Tofe <chris.chapuis@gmail.com>
   3 # Contributor: erm67 <erm67@yahoo.it>
   4
   5 pkgname=cairo-dock
   6 pkgver=3.4.1
   7 pkgrel=4
   8 pkgdesc='Light eye-candy fully themable animated dock'
   9 arch=('x86_64')
  10 url='https://glx-dock.org/'
  11 license=('GPL')
  12 depends=('curl' 'dbus-glib' 'glu' 'gtk3')
  13 makedepends=('bzr' 'cmake')
  14 optdepends=('cairo-dock-plug-ins: Plugins for Cairo-Dock')
  15 source=("cairo-dock-${pkgver}.tar.gz::https://github.com/Cairo-Dock/cairo-dock-core/archive/${pkgver}.tar.gz")
  16 sha256sums=('ca9b5769f60165b09d5cf2cae3c55fcc62fed19a279e8a279a0619f4189b4e00')
  17
  18 build() {
  19   cd cairo-dock-core-${pkgver}
  20
  21   if [[ -d build ]]; then
  22     rm -rf build
  23   fi
  24   mkdir build && cd build
  25
  26   cmake .. \
  27     -DCMAKE_BUILD_TYPE='Release' \
  28     -DCMAKE_INSTALL_PREFIX='/usr'
  29   make
  30 }
  31
  32 package() {
  33   cd cairo-dock-core-${pkgver}/build
  34
  35   make DESTDIR="${pkgdir}" install
  36 }
  37
  38 # vim: ts=2 sw=2 et: