cargo-make/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   3
   4 pkgname=cargo-make
   5 pkgver=0.36.7
   6 pkgrel=1
   7 pkgdesc='Rust task runner and build tool'
   8 arch=('x86_64')
   9 url='https://github.com/sagiegurari/cargo-make'
  10 license=('Apache')
  11 depends=('gcc-libs' 'openssl' 'bzip2')
  12 makedepends=('cargo')
  13 source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
  14 sha256sums=('acc3dabd6a30de8e5294bf002f6722d8efd51237dbf3a8f89696b81e26a6104e')
  15 options=('!lto')
  16
  17 prepare() {
  18   cd "$pkgname-$pkgver"
  19
  20   # download dependencies
  21   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  22 }
  23
  24 build() {
  25   cd "$pkgname-$pkgver"
  26
  27   cargo build --release --frozen
  28 }
  29
  30 package() {
  31   cd "$pkgname-$pkgver"
  32
  33   # binary
  34   install -vDm755 -t "$pkgdir/usr/bin" target/release/{cargo-make,makers}
  35
  36   # license
  37   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  38
  39   # documentation
  40   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" *.md
  41
  42   # shell auto-completion
  43   install -vDm644 extra/shell/makers-completion.bash "$pkgdir/usr/share/bash-completion/completions/makers"
  44 }
  45
  46 # vim:set ts=2 sw=2 et: