cargo-semver-checks/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2 # Contributor: KokaKiwi <kokakiwi+aur at kokakiwi dot net>
   3
   4 pkgname=cargo-semver-checks
   5 pkgver=0.20.1
   6 pkgrel=1
   7 pkgdesc='Scan your Rust crate for semver violations'
   8 url='https://github.com/obi1kenobi/cargo-semver-checks'
   9 license=('Apache' 'MIT')
  10 arch=('x86_64')
  11 depends=('gcc-libs' 'glibc' 'libgit2' 'openssl' 'zlib')
  12 makedepends=('cargo' 'git')
  13 _commit='719902274d1e695cca4055ba533b686645f5faa6'
  14 source=("$pkgname::git+$url.git#commit=$_commit")
  15 sha512sums=('SKIP')
  16 options=('!lto')
  17
  18 prepare() {
  19   cd "$pkgname"
  20   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  21 }
  22
  23 build() {
  24   cd "$pkgname"
  25   cargo build --release --frozen
  26 }
  27
  28
  29 check() {
  30   cd "$pkgname"
  31   ./scripts/regenerate_test_rustdocs.sh
  32   cargo test --frozen
  33 }
  34
  35 package() {
  36   cd "$pkgname"
  37   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  38   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  39   install -Dm 644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
  40 }
  41
  42 # vim:set ts=2 sw=2 et: