certbot-dns-inwx/trunk/PKGBUILD

   1 # Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>
   2
   3 pkgname='certbot-dns-inwx'
   4 pkgver=2.2.0
   5 pkgrel=3
   6 pkgdesc="INWX DNS authenticator plugin for certbot"
   7 arch=('any')
   8 url="https://github.com/oGGy990/certbot-dns-inwx"
   9 license=('Apache')
  10 depends=('certbot' 'python')
  11 makedepends=('python-build' 'python-installer' 'python-wheel')
  12 source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
  13 sha512sums=('67f40b50823f11c92750d5e961eb452b9cfde57a0a6c19863e07828f082615cc2a0282eb3d7c6c4ed192557dbaeeef7e2e98f1857b228557f1259e1a7ec0acc3')
  14 backup=(
  15   'etc/letsencrypt/inwx.cfg'
  16 )
  17
  18 build() {
  19   cd "${pkgname}-${pkgver}"
  20
  21   python -m build --wheel --skip-dependency-check --no-isolation
  22 }
  23
  24 package() {
  25   cd "${pkgname}-${pkgver}"
  26
  27   local _site_packages="$(python -c "import site; print(site.getsitepackages()[0])")"
  28
  29   python -m installer --destdir="${pkgdir}" dist/*.whl
  30
  31   install --verbose -D --mode=0600 inwx.cfg "${pkgdir}/etc/letsencrypt/inwx.cfg"
  32   install --verbose -D --mode=0644 README.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
  33
  34   # remove unneeded config file from site-packages
  35   rm --recursive --verbose "${pkgdir}${_site_packages}/etc"
  36 }