cl-fiveam/repos/community-any/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=cl-fiveam
   4 _pkgname="${pkgname#cl-}"
   5 pkgver=1.4.2.r12.ge11dee7
   6 pkgrel=2
   7 pkgdesc='A regression testing framework for Common Lisp'
   8 arch=('any')
   9 url='https://fiveam.common-lisp.dev'
  10 license=('MIT')
  11 depends=(
  12   'cl-asdf'
  13   'common-lisp'
  14   'cl-alexandria'
  15   'cl-asdf-flv'
  16   'cl-trivial-backtrace'
  17 )
  18 makedepends=('git')
  19 checkdepends=('sbcl')
  20 _commit='e11dee752a8f59065033ef9d60641d4a2f1e8379'
  21 source=(
  22   "$pkgname::git+https://github.com/lispci/fiveam#commit=$_commit"
  23   'run-tests.lisp'
  24 )
  25 b2sums=('SKIP'
  26         '40143c74430fb552a0cf7e9c309da2e25f0ed969c28b67206b4c60e2fd73d32cafc3e53e16fcde16326b9376aca7d5bc9cb5f472de2576c9d3958af7a93dd4f9')
  27
  28 pkgver() {
  29   cd "$pkgname"
  30
  31   git describe --tags | sed -e 's/^v//' -e 's/-/.r/' -e 's/-/./g'
  32 }
  33
  34 check() {
  35   cd "$pkgname"
  36
  37   sbcl --script ../run-tests.lisp
  38 }
  39
  40 package() {
  41   cd "$pkgname"
  42
  43   # library
  44   install -vd "$pkgdir/usr/share/common-lisp/source/$_pkgname"
  45   cp -vr \
  46     src t \
  47     fiveam.asd version.sexp \
  48     "$pkgdir/usr/share/common-lisp/source/$_pkgname"
  49
  50   # documentation
  51   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README
  52
  53   # license
  54   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" COPYING
  55 }