cl-hu-dwim-stefil/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=cl-hu-dwim-stefil
   4 _pkgname='hu.dwim.stefil'
   5 pkgver=r257.g7a17248
   6 pkgrel=2
   7 pkgdesc='A simple test framework in Common Lisp'
   8 arch=('any')
   9 url='https://github.com/hu-dwim/hu.dwim.stefil'
  10 license=('MIT')
  11 depends=('common-lisp' 'cl-asdf' 'cl-alexandria')
  12 makedepends=('git')
  13 checkdepends=('sbcl')
  14 _commit='7a172486ea51c5d38836e5b209d7135014506d19'
  15 source=(
  16   "$pkgname::git+$url#commit=$_commit"
  17   'run-tests.lisp'
  18 )
  19 b2sums=('SKIP'
  20         'f2db21db5957adcdf6ecf9c015795bcd03d982d961a2ea4ff7c4e53c8086d29c4fcaaa822358c4a1e9bebf5e3698d020afb1177715ed1f521ba772861ffc9b3e')
  21
  22 pkgver() {
  23   cd "$pkgname"
  24
  25   printf 'r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  26 }
  27
  28 check() {
  29   cd "$pkgname"
  30
  31   sbcl --script ../run-tests.lisp
  32 }
  33
  34 package() {
  35   cd "$pkgname"
  36
  37   # library
  38   install -vd "$pkgdir/usr/share/common-lisp/source/$_pkgname"
  39   cp -vr integration source test ./*.asd "$pkgdir/usr/share/common-lisp/source/$_pkgname"
  40
  41   # documentation
  42   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README
  43
  44   # license
  45   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENCE
  46 }