cl-trivial-features/repos/community-any/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=cl-trivial-features
   4 _pkgname="${pkgname#cl-}"
   5 pkgver=1.0.r3.g35c5eeb
   6 pkgrel=2
   7 pkgdesc='Ensure consistent features across multiple Common Lisp implementations'
   8 arch=('any')
   9 url='https://github.com/trivial-features/trivial-features'
  10 license=('MIT')
  11 depends=('common-lisp' 'cl-asdf')
  12 makedepends=('git')
  13 checkdepends=('sbcl' 'cl-rt' 'cl-cffi' 'cl-alexandria')
  14 _commit='35c5eeb21a51671ffbfcb591f84498e782478a32'
  15 source=(
  16   "$pkgname::git+$url#commit=$_commit"
  17   'run-tests.lisp'
  18 )
  19 b2sums=('SKIP'
  20         '6c7d4182131c8fea9efa23bb196200076c72b4d07caa88e01ea96a0ab9f12b8e4c20bff16fb2eec0630cb8907a274593b405a29193c7adc4bb2924a55213f4a4')
  21
  22 pkgver() {
  23   cd "$pkgname"
  24
  25   git describe --tags | sed -e 's/^v//' -e 's/-/.r/' -e 's/-/./g'
  26 }
  27
  28 check() {
  29   cd "$pkgname"
  30
  31   sbcl --script ../run-tests.lisp
  32 }
  33
  34 package() {
  35   cd "$pkgname"
  36
  37   # library
  38   install -vd "$pkgdir/usr/share/common-lisp/source/$_pkgname"
  39   cp -vr \
  40     src tests \
  41     ./*.{lisp,asd} \
  42     "$pkgdir/usr/share/common-lisp/source/$_pkgname"
  43
  44   # documentation
  45   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
  46
  47   # license
  48   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" COPYRIGHT
  49 }