d-stdx-allocator/trunk/PKGBUILD

   1 # Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
   2
   3 pkgname=d-stdx-allocator
   4 _pkgname=stdx-allocator
   5 pkgver=3.0.2
   6 pkgrel=21
   7 pkgdesc='Extracted std.experimental.allocator'
   8 arch=('x86_64')
   9 url='https://github.com/dlang-community/stdx-allocator'
  10 license=('Boost')
  11 depends=('liblphobos' 'd-mir-core')
  12 makedepends=('meson' 'ldc')
  13 source=("$_pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
  14         "add-dependency.patch::https://github.com/dlang-community/stdx-allocator/commit/676b4c782ba9c484864075508c27ef44399396f7.patch")
  15 sha512sums=('f4dc887225926cc4530314976e5e236c696a54c6e2ccdb48271b97b0c0a70882b70e92768c94c2932ccc9bd2282c3e953b27cf72088904458f7fc15234dca4be'
  16             '13d52d3bb4d90e7b5fb3163f1761c20a57a59be1306ac665fea0eb9331864821d77e790f8ca6027b1936a6930085d2ccca7a1d49d4bd139a939e2c58f03bd47a')
  17
  18 prepare() {
  19   cd $_pkgname-$pkgver
  20
  21   patch -p1 < ../add-dependency.patch
  22 }
  23
  24 build() {
  25   mkdir $_pkgname-$pkgver/build
  26   cd $_pkgname-$pkgver/build
  27
  28   export DC=ldc
  29   export LDFLAGS="$(echo -ne $LDFLAGS | sed -e 's/-flto=auto/-flto=full/')"
  30
  31   arch-meson ..
  32
  33   ninja
  34 }
  35
  36 check() {
  37   cd $_pkgname-$pkgver/build
  38
  39   meson test
  40 }
  41
  42 package() {
  43   cd $_pkgname-$pkgver/build
  44
  45   DESTDIR="$pkgdir" ninja install
  46 }