dbmate/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Marco A Rojas <marco.rojas@zentek.com.mx>
   3
   4 pkgname=dbmate
   5 pkgver=2.3.0
   6 pkgrel=1
   7 pkgdesc='A lightweight, framework-agnostic database migration tool'
   8 arch=('x86_64')
   9 url='https://github.com/amacneil/dbmate'
  10 license=('MIT')
  11 depends=('glibc')
  12 makedepends=('git' 'go')
  13 optdepends=(
  14   'mariadb: for local MariaDB instance'
  15   'postgresql: for local PostgreSQL instance'
  16   'sqlite: for local SQLite instance'
  17 )
  18 options=('!lto')
  19 _commit='f4610da0b9bc55d0298ac3be0bbc41a4f988d4c8'
  20 source=("$pkgname::git+$url.git#commit=$_commit")
  21 b2sums=('SKIP')
  22
  23 pkgver() {
  24   cd "$pkgname"
  25   git describe --tags | sed 's/^v//'
  26 }
  27
  28 prepare() {
  29   cd "$pkgname"
  30
  31   # create directory for build output
  32   mkdir build
  33
  34   # download dependencies
  35   export GOPATH="${srcdir}"
  36   go mod download
  37 }
  38
  39 build() {
  40   cd "$pkgname"
  41
  42   # set Go flags
  43   export CGO_CPPFLAGS="${CPPFLAGS}"
  44   export CGO_CFLAGS="${CFLAGS}"
  45   export CGO_CXXFLAGS="${CXXFLAGS}"
  46   export GOPATH="${srcdir}"
  47
  48   go build -v \
  49     -buildmode=pie \
  50     -mod=readonly \
  51     -modcacherw \
  52     -ldflags "-compressdwarf=false \
  53     -linkmode external \
  54     -extldflags ${LDFLAGS}" \
  55     -o build \
  56     .
  57 }
  58
  59 package() {
  60   cd "$pkgname"
  61
  62   # binary
  63   install -vDm755 -t "$pkgdir/usr/bin" "build/$pkgname"
  64
  65   # documentation
  66   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
  67
  68   # license
  69   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  70 }