deja-dup/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2
   3 pkgname=deja-dup
   4 pkgver=44.1
   5 pkgrel=1
   6 pkgdesc='A trivial-to-use personal backup tool to protect against accidental data loss'
   7 arch=('x86_64')
   8 url='https://wiki.gnome.org/Apps/DejaDup'
   9 license=('GPL')
  10 depends=(
  11   'duplicity'
  12   'gvfs'
  13   'libsecret'
  14   'org.freedesktop.secrets'
  15   'python-gobject'
  16   'python-pydrive2'
  17   'libadwaita'
  18 )
  19 makedepends=(
  20   'appstream-glib'
  21   'itstool'
  22   'meson'
  23   'vala'
  24 )
  25 source=("https://gitlab.gnome.org/World/$pkgname/-/archive/$pkgver/$pkgname-$pkgver.tar.gz")
  26 sha512sums=('8dc49a29fb027f77ca2141b9c3ed284c43de0a9dbb58cb0d2dabfcb811d0fe7ed792f946425a654dcf6b2408dc056dc2b753d6866ee356c2dc4fbfffe57cefd4')
  27 b2sums=('6e5163965a24af7b25988f59faaeb15519ecedc23a1a04ea6cfdb4fde2a84da44f2db33636b0a76ed718f64444c28fb22827f40f656ce122254a808fea2d6abb')
  28 validpgpkeys=('A3A5C2FC56AE7341D308D8571B50ECA373F3F233') # Michael Terry <mike@mterry.name>
  29
  30 prepare() {
  31   find "$pkgname-$pkgver" -name meson.build | xargs sed -e 's|C.UTF-8|C|' -i
  32 }
  33
  34 build() {
  35   arch-meson "$pkgname-$pkgver" build
  36   meson compile -C build
  37 }
  38
  39 check() {
  40   meson test -C build
  41 }
  42
  43 package() {
  44   meson install -C build --destdir "$pkgdir"
  45 }