fd/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
   3 # Contributor: Daniel M. Capella <polyzen@archlinux.info>
   4
   5 pkgname=fd
   6 pkgver=8.7.0
   7 pkgrel=1
   8 pkgdesc='Simple, fast and user-friendly alternative to find'
   9 arch=('x86_64')
  10 url=https://github.com/sharkdp/fd
  11 license=('MIT' 'APACHE')
  12 depends=('gcc-libs')
  13 makedepends=('rust')
  14 source=("fd-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
  15 sha512sums=('911b9b718f584bed7e569e11f098ede5effdb74822debca677b555e02032844ee7dd5644a5d7ad2d138d358025e08c02590a2ae2e99e8bac4ab1c88835e84c50')
  16
  17 build() {
  18   cd fd-$pkgver
  19   export CFLAGS+=" -ffat-lto-objects"
  20   cargo build --release --locked
  21 }
  22
  23 check() {
  24   cd fd-$pkgver
  25   cargo test --release --locked
  26 }
  27
  28 package() {
  29   cd fd-$pkgver
  30   install -Dm755 target/release/fd "$pkgdir"/usr/bin/fd
  31
  32   make completions
  33   install -Dm644 autocomplete/fd.bash "$pkgdir"/usr/share/bash-completion/completions/fd
  34   install -Dm644 autocomplete/fd.fish "$pkgdir"/usr/share/fish/vendor_completions.d/fd.fish
  35   install -Dm644 autocomplete/_fd "$pkgdir"/usr/share/zsh/site-functions/_fd
  36
  37   install -Dm644 doc/fd.1 "$pkgdir"/usr/share/man/man1/fd.1
  38   install -Dm644 LICENSE-APACHE "$pkgdir"/usr/share/licenses/fd/LICENSE-APACHE
  39   install -Dm644 LICENSE-MIT "$pkgdir"/usr/share/licenses/fd/LICENSE-MIT
  40 }
  41
  42 # vim:set ts=2 sw=2 et: