featherpad/trunk/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
   3 # Contributor: Peter Mattern <pmattern at arcor dot de>
   4
   5 pkgname=featherpad
   6 pkgver=1.4.0
   7 pkgrel=1
   8 pkgdesc='Lightweight Qt plain text editor'
   9 arch=('x86_64')
  10 url='https://github.com/tsujan/FeatherPad'
  11 license=('GPL3')
  12 depends=('hicolor-icon-theme' 'hunspell' 'qt6-svg')
  13 makedepends=('cmake' 'ninja' 'qt6-tools')
  14 source=("https://github.com/tsujan/FeatherPad/releases/download/V$pkgver/FeatherPad-$pkgver.tar.xz"{,.asc})
  15 sha256sums=('56d54ff6494a5ebfb628f7a6cabf370d09b9fb6f747b3533abeda6c3d8871671'
  16             'SKIP')
  17 validpgpkeys=('19DFDF3A579BD509DBB572D8BE793007AD22DF7E')
  18
  19 build() {
  20   cmake -B build -S FeatherPad-$pkgver \
  21         -G Ninja \
  22         -DCMAKE_INSTALL_PREFIX='/usr' \
  23         -DCMAKE_BUILD_TYPE=None \
  24         -DENABLE_QT5=OFF \
  25         -Wno-dev
  26   cmake --build build
  27 }
  28
  29 package() {
  30   DESTDIR="$pkgdir" cmake --install build
  31 }