feeluown/repos/community-any/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Bruce Zhang <zttt183525594@gmail.com>
   3
   4 pkgname=feeluown
   5 pkgver=3.8.11
   6 pkgrel=1
   7 pkgdesc="FeelUOwn Music Player"
   8 arch=('any')
   9 url="https://github.com/feeluown/FeelUOwn"
  10 license=('GPL3')
  11 depends=('python-qasync' 'python-pyqt5' 'mpv' 'python-opengl' 'python-janus' 'python-requests'
  12          'python-tomlkit' 'python-packaging' 'python-pydantic' 'python-mutagen' 'qt5-svg')
  13 makedepends=('python-setuptools')
  14 checkdepends=('python-pytest-benchmark' 'python-pytest-cov')
  15 optdepends=('feeluown-local' 'feeluown-netease' 'feeluown-qqmusic' 'feeluown-kuwo' 'feeluown-bilibili')
  16 groups=('feeluown-full')
  17 source=("https://pypi.io/packages/source/f/feeluown/feeluown-$pkgver.tar.gz"
  18         "feeluown.desktop")
  19 sha512sums=('d7a63fd62e81f51e4cecf42e22e464fb2dc032ac7574d5750f2659fac7828d31728cef4638a4afd7bfe79f723402835246a843bc327e07f92a3e2f2089d91398'
  20             '48882f7469c22e5db332663bc1aa8b398b0a10a0c929d4d7e3d7b8b91205d7d3070c5fa295cb9a14f8c352bff57978bfaad167343e0ddc51c92417eda07c8087')
  21
  22 build() {
  23   cd $pkgname-$pkgver
  24   python setup.py build
  25 }
  26
  27 check() {
  28   cd $pkgname-$pkgver
  29   pytest
  30 }
  31
  32 package() {
  33   cd $pkgname-$pkgver
  34   python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
  35   install -Dm644 feeluown/gui/assets/icons/feeluown.png -t "$pkgdir"/usr/share/icons/hicolor/512x512/apps/
  36   install -Dm644 "$srcdir"/feeluown.desktop -t "$pkgdir"/usr/share/applications/
  37 }