findomain/repos/community-x86_64/PKGBUILD

   1 # Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
   2 # Contributor: Eduard Tolosa <edu4rdshl@protonmail.com>
   3
   4 pkgname=findomain
   5 _pkgname=Findomain
   6 pkgver=9.0.0
   7 pkgrel=1
   8 pkgdesc='The fastest and cross-platform subdomain enumerator, do not waste your time'
   9 url='https://github.com/Findomain/Findomain'
  10 arch=('x86_64')
  11 license=('GPL3')
  12 depends=('gcc-libs')
  13 makedepends=('cargo')
  14 optdepends=('postgresql: for subdomain monitoring')
  15 source=("https://github.com/${_pkgname}/${_pkgname}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
  16 b2sums=('7a10fc64e8aa161bed8f304bb4e1aff8298642123fb0798f80bc094a84ef3e951856b735822a55294223284df7b289baf27131878ee1e9071ba4327d7669d2c4')
  17 options=(!lto)
  18
  19 build() {
  20   cd ${_pkgname}-${pkgver}
  21   cargo build --release --locked
  22 }
  23
  24 check() {
  25   cd ${_pkgname}-${pkgver}
  26   cargo test --release --locked
  27 }
  28
  29 package() {
  30   cd ${_pkgname}-${pkgver}
  31
  32   install -Dm 755 "target/release/${pkgname}" -t "${pkgdir}/usr/bin"
  33   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  34   install -Dm 644 "${pkgname}.1" -t "${pkgdir}/usr/share/man/man1"
  35 }
  36
  37 # vim: ts=2 sw=2 et: