firefox-tree-style-tab/repos/community-any/PKGBUILD

   1 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
   2 # Contributor: Jérémie Detrey <Jeremie.Detrey@loria.fr>
   3
   4 _name=treestyletab
   5 pkgname=firefox-tree-style-tab
   6 pkgver=3.9.15
   7 pkgrel=1
   8 pkgdesc='Firefox extension to show tabs like a tree'
   9 arch=('any')
  10 url=https://piro.sakura.ne.jp/xul/_treestyletab.html.en
  11 license=('MPL' 'MPL2')
  12 groups=('firefox-addons')
  13 makedepends=('git' 'npm' 'strip-nondeterminism' 'zip')
  14 source=("git+https://github.com/piroor/treestyletab.git#tag=$pkgver"
  15         'git+https://github.com/piroor/webextensions-lib-configs.git'
  16         'git+https://github.com/piroor/webextensions-lib-dom-updater.git'
  17         'git+https://github.com/piroor/webextensions-lib-event-listener-manager.git'
  18         'git+https://github.com/piroor/webextensions-lib-l10n.git'
  19         'git+https://github.com/piroor/webextensions-lib-menu-ui.git'
  20         'git+https://github.com/piroor/webextensions-lib-options.git'
  21         'git+https://github.com/piroor/webextensions-lib-rich-confirm.git'
  22         'git+https://github.com/piroor/webextensions-lib-shortcut-customize-ui.git'
  23         'git+https://github.com/piroor/webextensions-lib-tab-favicon-helper.git')
  24 b2sums=('SKIP'
  25         'SKIP'
  26         'SKIP'
  27         'SKIP'
  28         'SKIP'
  29         'SKIP'
  30         'SKIP'
  31         'SKIP'
  32         'SKIP'
  33         'SKIP')
  34
  35 prepare() {
  36   cd $_name
  37   git submodule init
  38   for i in ../webextensions*; do
  39     git config submodule.submodules/"${i##../}".url "$i"
  40   done
  41   git -c protocol.file.allow=always submodule update
  42   cd webextensions
  43   sed -i 's/^\(install_extlib\|xpi\): .*/\1:/' Makefile
  44   npm ci
  45 }
  46
  47 build() {
  48   cd $_name/webextensions
  49   make install_extlib
  50   make xpi
  51   strip-nondeterminism -t zip $_name-we.xpi
  52 }
  53
  54 package() {
  55   cd $_name/webextensions
  56   install -Dm644 $_name-we.xpi \
  57     "$pkgdir"/usr/lib/firefox/browser/extensions/$_name@piro.sakura.ne.jp.xpi
  58 }