fish/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Kaiting Chen <kaitocracy@gmail.com>
   4 # Contributor: Abhishek Dasgupta <abhidg@gmail.com>
   5 # Contributor: Eric Belanger <eric@archlinux.org>
   6 # Contributor: Jan Fader <jan.fader@web.de>
   7
   8 pkgname=fish
   9 pkgver=3.6.1
  10 pkgrel=1
  11 pkgdesc='Smart and user friendly shell intended mostly for interactive use'
  12 url='https://fishshell.com/'
  13 arch=('x86_64')
  14 license=('GPL2')
  15 depends=('glibc' 'gcc-libs' 'ncurses' 'pcre2')
  16 optdepends=('python: man page completion parser / web config tool'
  17             'pkgfile: command-not-found hook')
  18 makedepends=('cmake' 'python-sphinx')
  19 checkdepends=('expect' 'procps-ng')
  20 install=fish.install
  21 backup=(etc/fish/config.fish)
  22 source=(https://github.com/fish-shell/fish-shell/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.xz{,.asc})
  23 validpgpkeys=(003837986104878835FA516D7A67D962D88A709A) # David Adam <zanchey@gmail.com>
  24 sha256sums=('55402bb47ca6739d8aba25e41780905b5ce1bce0a5e0dd17dca908b5bc0b49b2'
  25             'SKIP')
  26 sha512sums=('ee6f5c7699307d515f111c8c4f1633d9eb9703e045a93cfc2fcec722a03cca4ab25e4e09f6fd94ff2d07180d8b37c6ab733323bb2645065fdeb4e94771347597'
  27             'SKIP')
  28
  29 build() {
  30   cd ${pkgname}-${pkgver}
  31   export CXXFLAGS+=" ${CPPFLAGS}"
  32   cmake \
  33     -B build \
  34     -DCMAKE_INSTALL_PREFIX=/usr \
  35     -DCMAKE_INSTALL_SYSCONFDIR=/etc \
  36     -DCMAKE_BUILD_TYPE=None \
  37     -DBUILD_DOCS=True \
  38     -Wno-dev
  39   make -C build VERBOSE=1
  40 }
  41
  42 check() {
  43   cd ${pkgname}-${pkgver}
  44   make -C build test
  45 }
  46
  47 package() {
  48   cd ${pkgname}-${pkgver}
  49   make -C build DESTDIR="${pkgdir}" install
  50 }
  51
  52 # vim: ts=2 sw=2 et: