frescobaldi/trunk/PKGBUILD

   1 # Maintainer: Bruno Pagani <archange@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3
   4 pkgname=frescobaldi
   5 pkgver=3.3.0
   6 pkgrel=2
   7 pkgdesc="A LilyPond sheet music text editor"
   8 arch=(any)
   9 url="https://www.frescobaldi.org/"
  10 license=(GPL)
  11 depends=(
  12   python python-pyqt5 python-pyqt5-webengine python-ly poppler
  13   python-poppler-qt5 python-qpageview qt5-base qt5-svg
  14 )
  15 makedepends=(python-{build,installer,wheel}
  16              python-setuptools)
  17 optdepends=(
  18   'lilypond: music engraving'
  19   'python-pygame: MIDI input and playback'
  20   'python-pycups: printing to a CUPS server'
  21   'hyphen-lang: hyphenation patterns for desired languages'
  22 )
  23 source=(https://github.com/frescobaldi/frescobaldi/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  24 sha256sums=('9fb90934fbc08f6c7df0a4d999e89a9a82fe9b4a0f21c0d40a1474e3ac7bc0d8')
  25
  26 prepare() {
  27   cd ${pkgname}-${pkgver}
  28   # Provided by hyphen-*
  29   rm -f frescobaldi_app/hyphdicts/hyph_*.dic
  30   rm -f frescobaldi_app/hyphdicts/README*
  31 }
  32
  33 build() {
  34   cd ${pkgname}-${pkgver}
  35   python -m build -wn
  36 }
  37
  38 package() {
  39   cd ${pkgname}-${pkgver}
  40   python -m installer -d "${pkgdir}" dist/*.whl
  41 }