gfold/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3
   4 pkgname=gfold
   5 _commit='1d768381bd0fb16684e64911ebe4eb7c67f6ba50'
   6 pkgver=4.3.3
   7 pkgrel=1
   8 pkgdesc="A CLI tool to help keep track of Git repositories"
   9 arch=('x86_64')
  10 url="https://github.com/nickgerace/gfold"
  11 license=('Apache')
  12 depends=('libgit2')
  13 makedepends=('cargo' 'git')
  14 source=("$pkgname::git+$url.git#commit=$_commit")
  15 sha512sums=('SKIP')
  16
  17 prepare() {
  18   cd "$pkgname"
  19   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  20 }
  21
  22 build() {
  23   cd "$pkgname"
  24   CFLAGS+=" -ffat-lto-objects"
  25   cargo build --release --frozen
  26 }
  27
  28 check() {
  29   cd "$pkgname"
  30   cargo test --frozen
  31 }
  32
  33 package() {
  34   cd "$pkgname"
  35   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  36   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  37 }
  38
  39 # vim: ts=2 sw=2 et: