git-annex/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Arch Haskell Team <arch-haskell@haskell.org>
   4
   5 pkgname=git-annex
   6 pkgver=10.20230329
   7 pkgrel=15
   8 pkgdesc="Manage files with git, without checking their contents into git"
   9 url="https://git-annex.branchable.com/"
  10 license=("AGPL3")
  11 arch=('x86_64')
  12 depends=('git' 'lsof' 'rsync' 'ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-async'
  13          'haskell-aws' 'haskell-blaze-builder' 'haskell-bloomfilter' 'haskell-byteable'
  14          'haskell-case-insensitive' 'haskell-clientsession' 'haskell-concurrent-output'
  15          'haskell-connection' 'haskell-conduit' 'haskell-criterion' 'haskell-crypto-api'
  16          'haskell-cryptonite' 'haskell-data-default' 'haskell-dav' 'haskell-dbus'
  17          'haskell-disk-free-space' 'haskell-dlist' 'haskell-edit-distance' 'haskell-fdo-notify'
  18          'haskell-feed' 'haskell-filepath-bytestring' 'haskell-git-lfs' 'haskell-hinotify'
  19          'haskell-http-client' 'haskell-http-client-restricted' 'haskell-http-client-tls'
  20          'haskell-http-conduit' 'haskell-http-types' 'haskell-ifelse' 'haskell-magic'
  21          'haskell-memory' 'haskell-microlens' 'haskell-monad-control' 'haskell-monad-logger'
  22          'haskell-mountpoints' 'haskell-network' 'haskell-network-info' 'haskell-network-multicast'
  23          'haskell-network-uri' 'haskell-old-locale' 'haskell-optparse-applicative'
  24          'haskell-path-pieces' 'haskell-persistent' 'haskell-persistent-sqlite' 'haskell-quickcheck'
  25          'haskell-random' 'haskell-regex-tdfa' 'haskell-resourcet' 'haskell-safesemaphore'
  26          'haskell-sandi' 'haskell-securemem' 'haskell-shakespeare' 'haskell-socks' 'haskell-split'
  27          'haskell-stm-chans' 'haskell-tagsoup' 'haskell-tasty' 'haskell-tasty-hunit'
  28          'haskell-tasty-quickcheck' 'haskell-tasty-rerun' 'haskell-torrent' 'haskell-unix-compat'
  29          'haskell-unliftio-core' 'haskell-unordered-containers' 'haskell-utf8-string' 'haskell-uuid'
  30          'haskell-vector' 'haskell-wai' 'haskell-wai-extra' 'haskell-warp' 'haskell-warp-tls'
  31          'haskell-yesod' 'haskell-yesod-core' 'haskell-yesod-form' 'haskell-yesod-static')
  32 makedepends=('chrpath' 'ghc' 'uusi')
  33 source=("git+https://git.joeyh.name/git/git-annex.git#tag=$pkgver")
  34 sha512sums=('SKIP')
  35
  36 prepare() {
  37   cd git-annex
  38   # persistent-template was merged into persistent
  39   uusi -d persistent-template git-annex.cabal
  40   sed -i 's/MIN_VERSION_persistent_template/MIN_VERSION_persistent/' Database/ContentIdentifier.hs Database/Export.hs Database/Fsck.hs Database/Keys/SQL.hs
  41 }
  42
  43 build() {
  44   cd git-annex
  45   sed -e 's|--ghc-options|-O --prefix=/usr --enable-executable-dynamic --disable-library-vanilla --docdir=/usr/share/doc/'$pkgname' --ghc-options|' \
  46       -i Makefile
  47   make GHC="ghc -dynamic" BUILDER=./Setup BUILDEROPTIONS=$MAKEFLAGS
  48 }
  49
  50 package() {
  51   cd git-annex
  52   make GHC="ghc -dynamic" BUILDER=./Setup DESTDIR="$pkgdir" install
  53
  54   rmdir "$pkgdir"/usr/share/doc/git-annex "$pkgdir"/usr/share/doc
  55 }