git-delta/repos/community-x86_64/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Kr1ss $(echo \<kr1ss+x-yandex+com\>|sed s/\+/./g\;s/\-/@/)
   4 # Contributor: ccorn
   5
   6 pkgname=git-delta
   7 _pkgname=delta
   8 pkgver=0.15.1
   9 pkgrel=2
  10 pkgdesc='Syntax-highlighting pager for git and diff output'
  11 arch=('x86_64')
  12 url='https://github.com/dandavison/delta'
  13 license=('MIT')
  14 depends=('libgit2.so')
  15 makedepends=('cargo' 'mdbook')
  16 checkdepends=('git')
  17 source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
  18 sha512sums=('646244299ec79d59ff91fd0b2d9600795a6c0e4f3f6efa6629217a6847d6b736ceed45bd52435aeb25cd80ffa9630bf9cebce35312fead3de2bb5b0d04e790c4')
  19 b2sums=('b29972e8fb1e640ced5f8148610a17177e08cda2988189bd3cad585937c85b8b749cf3e3fd4648599462b4272d4f3b99448cead13a688289732106e744a294d5')
  20
  21 prepare() {
  22   cd "$_pkgname-$pkgver"
  23
  24   # download dependencies
  25   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  26 }
  27
  28 build() {
  29   cd "$_pkgname-$pkgver"
  30
  31   # https://archlinux.org/todo/lto-fat-objects/
  32   CFLAGS+=' -ffat-lto-objects'
  33
  34   # binary
  35   cargo build --frozen --release --all-features
  36
  37   # html manual
  38   cd manual
  39   mdbook build --dest-dir html
  40 }
  41
  42 check() {
  43   cd "$_pkgname-$pkgver"
  44   # some tests hang for 60+ seconds, find out why
  45   # took my machine ~ 470 seconds
  46   cargo test --frozen --all-features
  47 }
  48
  49 package() {
  50   cd "$_pkgname-$pkgver"
  51
  52   # binary
  53   install -vDm755 -t "$pkgdir/usr/bin" target/release/delta
  54
  55   # license
  56   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  57
  58   # shell auto-completions
  59   install -vDm644 etc/completion/completion.bash \
  60     "$pkgdir/usr/share/bash-completion/completions/$_pkgname"
  61   install -vDm644 etc/completion/completion.zsh \
  62     "$pkgdir/usr/share/zsh/site-functions/_$_pkgname"
  63   install -vDm644 etc/completion/completion.fish \
  64     "$pkgdir/usr/share/fish/vendor_completions.d/$_pkgname.fish"
  65
  66   # documentation
  67   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
  68
  69   # html manual
  70   cp -r manual/html "$pkgdir/usr/share/doc/$pkgname"
  71 }