gitui/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Simon Hauser <Simon-Hauser@outlook.de>
   4 # Contributor: Wesley Moore <wes@wezm.net>
   5
   6 pkgname=gitui
   7 pkgver=0.22.1
   8 pkgrel=2
   9 pkgdesc='Blazing fast terminal-ui for git written in Rust'
  10 url='https://github.com/extrawurst/gitui'
  11 arch=('x86_64')
  12 license=('MIT')
  13 # work around two libssl.so providers being in the repos by only depending on package for now
  14 depends=('gcc-libs' 'libgit2.so' 'libxcb' 'openssl' 'zlib')
  15 makedepends=('cargo' 'python') # xcb crate needs python
  16 source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
  17 sha256sums=('285e86c136ee7f410fdd52c5284ccf0d19011cc5f7709e5e10bb02f439a218ea')
  18 b2sums=('10efce18cfe2a4a7de348da5c6ebdb230d333524a48e7a086546ed8313b0301c886577f909bafe0851986a1070f44fad76eabf1479c1e733717857d8f78b4fed')
  19
  20 prepare() {
  21   cd "${pkgname}-${pkgver}"
  22   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  23 }
  24
  25 build() {
  26   cd "${pkgname}-${pkgver}"
  27   CFLAGS+=" -ffat-lto-objects"
  28   cargo build --frozen --release
  29 }
  30
  31 check() {
  32   cd "${pkgname}-${pkgver}"
  33   cargo test --frozen
  34 }
  35
  36 package() {
  37   cd "${pkgname}-${pkgver}"
  38   install -Dm 755 target/release/gitui -t "${pkgdir}/usr/bin/"
  39   install -Dm 644 {KEY_CONFIG,README,THEMES}.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  40   install -Dm 644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
  41 }
  42
  43 # vim: ts=2 sw=2 et: