gnormalize/trunk/PKGBUILD

   1 # Maintainer: Alexander F Rødseth <xyproto@archlinux.org>
   2 # Contributor: Chris Brannon <cmbrannon79@gmail.com>
   3 # Contributor: Corrado Primier <bardo@aur.archlinux.org>
   4 # Contributor: JZsolt Varadi (karmaxxl)
   5
   6 pkgname=gnormalize
   7 pkgver=0.63
   8 pkgrel=7
   9 pkgdesc='Audio normalizer, converter, encoder/decoder, ripper, tagger and player'
  10 arch=('any')
  11 url='https://gnormalize.sourceforge.net/'
  12 license=('GPL')
  13 depends=('cddb_get' 'gtk2-perl')
  14 makedepends=('gendesk')
  15 optdepends=('faac: full MP4 format'
  16             'flac: FLAC encoding, FLAC playing in conjunction with mplayer'
  17             'lame: MP3 encoding'
  18             'mac: full Monkeys Audio Codec support (available in the AUR)'
  19             'mpg123: MP3 playing'
  20             'mplayer: FLAC/WAV playing'
  21             'musepack-tools: full Musepack support'
  22             'perl-mp3-info: MP3 ID3 tags'
  23             'vorbis-tools: full OGG Vorbis support'
  24             'cdcd: CD playing'
  25             'cdparanoia: CD ripping'
  26             'cdrkit: CD ripping - alternative to cdparanoia'
  27             'wavegain: sound normalization')
  28 source=("https://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz")
  29 sha256sums=('80fd9aa2da8d7fcc88bd180be2adce1aed863bedba7d715144029bd95b61ccb6')
  30
  31 prepare() {
  32   cd "$pkgname-$pkgver"
  33
  34   lzma -qd gnormalize.1.lzma
  35   gendesk -f -n \
  36     --pkgname "$pkgname" \
  37     --pkgdesc "$pkgdesc" \
  38     --mimetypes 'audio/mp3;audio/x-mp3;audio/mpeg;audio/x-mpeg;audio/x-wav;application/x-ogg'
  39 }
  40
  41 package() {
  42   cd "$pkgname-$pkgver"
  43
  44   install -Dm755 "$pkgname" "$pkgdir/usr/bin/$pkgname"
  45   install -Dm644 "$pkgname.1" "$pkgdir/usr/share/man/man1/$pkgname.1"
  46   install -d "$pkgdir/usr/share/$pkgname/animations"
  47   install -m644 animations/*.gif "$pkgdir/usr/share/$pkgname/animations/"
  48   install -Dm644 README "$pkgdir/usr/share/doc/$pkgname/README"
  49   install -Dm644 "icons/$pkgname.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
  50   install -Dm644 "$pkgname.desktop" \
  51     "$pkgdir/usr/share/applications/$pkgname.desktop"
  52   for i in 16 32 48 ; do
  53     install -Dm644 "icons/gnormalize-$i.png" \
  54       "$pkgdir/usr/share/icons/hicolor/${i}x$i/apps/$pkgname.png"
  55   done
  56 }
  57
  58 # vim: ts=2 sw=2 et: