goocanvasmm/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
   2 # Contributor: Thomas Dziedzic < gostrc at gmail >
   3 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   4 # Contributor: Laurent Meunier <laurent@deltalima.net>
   5
   6 pkgname=goocanvasmm
   7 pkgver=1.90.11
   8 pkgrel=7
   9 pkgdesc='C++ wrappers for goocanvas'
  10 arch=('x86_64')
  11 url='https://download.gnome.org/sources/goocanvasmm/'
  12 license=('GPL')
  13 depends=('goocanvas' 'gtkmm3')
  14 makedepends=('mm-common')
  15 source=(https://download.gnome.org/sources/goocanvasmm/1.90/goocanvasmm-${pkgver}.tar.xz)
  16 sha512sums=('f4decc16fc927dd044714558d1edd5a1dc53bc084b1ad361f791bb3f21bedd298a14aa603e3087df7c61d6d873c86a5b00e1ff82cffa5cafa7f06e86b59a7241')
  17
  18 prepare() {
  19   cd ${pkgname}-${pkgver}
  20   sed -i 's/goocanvas-2.0/goocanvas-3.0/' configure.ac
  21   autoreconf -fiv
  22 }
  23
  24 build() {
  25   cd ${pkgname}-${pkgver}
  26
  27   ./configure \
  28     --prefix=/usr \
  29     --disable-static \
  30     --disable-documentation
  31
  32   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  33
  34   make
  35 }
  36
  37 package() {
  38   cd ${pkgname}-${pkgver}
  39
  40   make DESTDIR="${pkgdir}" install
  41 }