handbrake/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: Sebastien Piccand <sebcactus gmail com>
   4
   5 pkgname=('handbrake' 'handbrake-cli')
   6 pkgver=1.6.1
   7 pkgrel=2
   8 arch=('x86_64')
   9 url="https://handbrake.fr/"
  10 license=('GPL')
  11 _commondeps=('libxml2' 'libass' 'libvorbis' 'opus' 'speex' 'libtheora' 'lame'
  12              'x264' 'jansson' 'libvpx' 'libva' 'numactl' 'bzip2' 'gcc-libs'
  13              'zlib' 'xz' 'libjpeg-turbo')
  14 _guideps=('gst-plugins-base' 'gtk3' 'librsvg' 'libgudev')
  15 makedepends=('intltool' 'python' 'nasm' 'wget' 'cmake' 'meson'
  16              "${_commondeps[@]}" "${_guideps[@]}")
  17 options=('!lto') # https://bugs.archlinux.org/task/72600
  18 source=(https://github.com/HandBrake/HandBrake/releases/download/$pkgver/HandBrake-$pkgver-source.tar.bz2{,.sig})
  19 sha256sums=('94ccfe03db917a91650000c510f7fd53f844da19f19ad4b4be1b8f6bc31a8d4c'
  20             'SKIP')
  21 validpgpkeys+=('1629C061B3DDE7EB4AE34B81021DB8B44E4A8645') # HandBrake Team <developers@handbrake.fr>
  22
  23 prepare() {
  24   cd HandBrake-$pkgver
  25 }
  26
  27 build() {
  28   cd HandBrake-$pkgver
  29
  30   ./configure \
  31     --prefix=/usr \
  32     --enable-qsv
  33   make -C build
  34 }
  35
  36 package_handbrake() {
  37   pkgdesc="Multithreaded video transcoder"
  38   depends=('desktop-file-utils' 'hicolor-icon-theme'
  39            "${_commondeps[@]}" "${_guideps[@]}")
  40   optdepends=('gst-plugins-good: for video previews'
  41               'gst-libav: for video previews'
  42               'intel-media-sdk: Intel QuickSync support'
  43               'libdvdcss: for decoding encrypted DVDs')
  44
  45   cd HandBrake-$pkgver/build
  46
  47   make DESTDIR="$pkgdir" install
  48   rm "$pkgdir/usr/bin/HandBrakeCLI"
  49 }
  50
  51 package_handbrake-cli() {
  52   pkgdesc="Multithreaded video transcoder (CLI)"
  53   depends=("${_commondeps[@]}")
  54   optdepends=('intel-media-sdk: Intel QuickSync support'
  55               'libdvdcss: for decoding encrypted DVDs')
  56
  57   cd HandBrake-$pkgver/build
  58   install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
  59 }
  60
  61 # vim:set ts=2 sw=2 et: