haskell-hls-fourmolu-plugin/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 _hkgname=hls-fourmolu-plugin
   4 pkgname=haskell-hls-fourmolu-plugin
   5 pkgver=1.1.1.0
   6 pkgrel=16
   7 pkgdesc="Integration with the Fourmolu code formatter"
   8 url="https://hackage.haskell.org/package/hls-fourmolu-plugin"
   9 license=("Apache")
  10 arch=('x86_64')
  11 depends=('ghc-libs' 'haskell-fourmolu' 'haskell-ghc' 'haskell-ghcide' 'haskell-hls-plugin-api'
  12          'haskell-lens' 'haskell-lsp' 'haskell-process-extras')
  13 makedepends=('ghc' 'uusi' 'haskell-aeson' 'haskell-hls-test-utils' 'haskell-lsp-test')
  14 checkdepends=('git')
  15 source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
  16 sha512sums=('5d266e0f37944b8199cf63b25f0de9fe85cff133715cadf9062147712e5e4e750177d3210dec247286b6f3eab8794822fa6f706f3afc4a71e7ec5395a53e3284')
  17
  18 prepare() {
  19   cd $_hkgname-$pkgver
  20   gen-setup
  21 }
  22
  23 build() {
  24   cd $_hkgname-$pkgver
  25
  26   runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
  27     --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
  28     --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
  29     --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
  30     --ghc-option='-pie'
  31
  32   runhaskell Setup build $MAKEFLAGS
  33   runhaskell Setup register --gen-script
  34   runhaskell Setup unregister --gen-script
  35   sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
  36   sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
  37 }
  38
  39 check() {
  40   cd $_hkgname-$pkgver
  41   runhaskell Setup test --show-details=direct
  42 }
  43
  44 package() {
  45   cd $_hkgname-$pkgver
  46
  47   install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
  48   install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
  49   runhaskell Setup copy --destdir="$pkgdir"
  50   install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  51   rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
  52 }