hex/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2 # Contributor: Sven-Hendrik Haase <svenstaro@gmail.com>
   3
   4 pkgname=hex
   5 pkgver=0.4.2
   6 pkgrel=2
   7 pkgdesc="Futuristic take on hexdump"
   8 arch=('x86_64')
   9 url="https://github.com/sitkevij/hex"
  10 license=(MIT)
  11 depends=('gcc-libs')
  12 makedepends=('rust')
  13 source=($pkgname-$pkgver.tar.gz::https://github.com/sitkevij/hex/archive/v${pkgver}.tar.gz)
  14 sha512sums=('5b5706d931c4f6a9a21de5e883b264c9a2831a8be463a5283ac4cd3552eb44c480f45779fa6364dd97390a2d38f252b44313e4567186ec42c594451f295e648f')
  15
  16 prepare() {
  17   cd "$srcdir/$pkgname-$pkgver"
  18
  19   cargo fetch --locked
  20 }
  21
  22 build() {
  23   cd "$srcdir/$pkgname-$pkgver"
  24
  25   cargo build --release --frozen
  26 }
  27
  28 check() {
  29   cd "$srcdir/$pkgname-$pkgver"
  30
  31   cargo build --frozen
  32   cargo test --frozen
  33 }
  34
  35 package() {
  36   cd "$srcdir/$pkgname-$pkgver"
  37
  38   install -Dm755 target/release/hx "$pkgdir"/usr/bin/hx
  39   install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  40   install -Dm644 README.md "$pkgdir"/usr/share/doc/$pkgname/README.md
  41 }
  42
  43 # vim:set ts=2 sw=2 et: