hledger-ui/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Arch Haskell Team <arch-haskell@haskell.org>
   4
   5 pkgname=hledger-ui
   6 pkgver=1.28
   7 pkgrel=34
   8 pkgdesc="Curses-style terminal interface for the hledger accounting system"
   9 url="http://hledger.org"
  10 license=("GPL")
  11 arch=('x86_64')
  12 depends=('ghc-libs' 'hledger' 'haskell-hledger-lib' 'haskell-ansi-terminal' 'haskell-async'
  13          'haskell-cmdargs' 'haskell-data-default' 'haskell-doclayout' 'haskell-extra'
  14          'haskell-fsnotify' 'haskell-microlens' 'haskell-microlens-platform' 'haskell-megaparsec'
  15          'haskell-safe' 'haskell-split' 'haskell-text-zipper' 'haskell-vector' 'haskell-brick'
  16          'haskell-vty')
  17 makedepends=('ghc')
  18 source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
  19 sha512sums=('eeac3483daee66449706535c1c4e0978ee359bd3ace071d7d208ab2c8b45d7276a478bb9fde7bc60cb83d59c5f6d82008cc87d4c145f4dee18bb667bc5163d0f')
  20
  21 build() {
  22     cd $pkgname-$pkgver
  23     runhaskell Setup configure -O --enable-executable-dynamic --disable-library-vanilla \
  24         --prefix=/usr --docdir="/usr/share/doc/$pkgname" --datasubdir=$pkgname --enable-tests \
  25             -fthreaded
  26     runhaskell Setup build $MAKEFLAGS
  27 }
  28
  29 check() {
  30     cd $pkgname-$pkgver
  31     runhaskell Setup test --show-details=direct
  32 }
  33
  34 package() {
  35     cd $pkgname-$pkgver
  36     runhaskell Setup copy --destdir="$pkgdir"
  37     rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
  38
  39     install -Dm644 hledger-ui.1 -t "$pkgdir"/usr/share/man/man1/
  40 }