i3-gaps/trunk/PKGBUILD

   1 # Maintainer: Morten Linderud <foxboron@archlinux.org>
   2 # Contributor: Ingo Bürk <admin at airblader dot de>
   3
   4 pkgname=i3-gaps
   5 pkgver=4.21.1
   6 pkgrel=1
   7 pkgdesc='A fork of i3wm tiling window manager with more features, including gaps'
   8 arch=('i686' 'x86_64')
   9 url='https://github.com/Airblader/i3'
  10 license=('BSD')
  11 provides=('i3-wm')
  12 conflicts=('i3-wm')
  13 groups=('i3')
  14 depends=('xcb-util-keysyms' 'xcb-util-wm' 'libev' 'yajl'
  15          'startup-notification' 'pango' 'perl' 'xcb-util-cursor' 'xcb-util-xrm'
  16          'libxkbcommon-x11')
  17 makedepends=('bison' 'flex' 'asciidoc' 'xmlto' 'meson')
  18 optdepends=('rxvt-unicode: The terminal emulator used in the default config.'
  19             'dmenu: As menu.'
  20             'i3lock: For locking your screen.'
  21             'i3status: To display system information with a bar.'
  22             'perl-json-xs: For i3-save-tree'
  23             'perl-anyevent-i3: For i3-save-tree')
  24 backup=(etc/i3/config)
  25 options=('docs')
  26 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/Airblader/i3/archive/${pkgver}.tar.gz")
  27 sha256sums=('83f9b375c70f015611216cfa56956945c5b731c9943c53f4e3d6dee305de54f6')
  28
  29 build() {
  30   cd "i3-${pkgver}"
  31   arch-meson \
  32     -Ddocs=true \
  33     -Dmans=true \
  34   ../build
  35   meson compile -C ../build
  36 }
  37
  38 package() {
  39   cd "i3-${pkgver}"
  40   DESTDIR="$pkgdir" meson install -C ../build
  41   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE
  42 }
  43
  44 # vim:set ts=2 sw=2 et: