innoextract/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Alad Wenter <alad@mailbox.org>
   2 # Contributor: carstene1ns <arch carsten-teibes de>
   3 # Contributor: Sam S. <smls75@gmail.com>
   4 # Contributor: Daniel Scharrer <daniel@constexpr.org>
   5 pkgname=innoextract
   6 pkgver=1.9
   7 pkgrel=8
   8 pkgdesc="A tool to extract installers created by Inno Setup"
   9 url='https://constexpr.org/innoextract/'
  10 arch=('x86_64')
  11 license=('ZLIB')
  12 depends=('boost-libs' 'xz')
  13 makedepends=('boost' 'cmake')
  14 source=("https://constexpr.org/innoextract/files/$pkgname-$pkgver.tar.gz"
  15         "https://constexpr.org/innoextract/files/$pkgname-$pkgver.tar.gz.sig")
  16 sha256sums=('6344a69fc1ed847d4ed3e272e0da5998948c6b828cb7af39c6321aba6cf88126'
  17             'SKIP')
  18 validpgpkeys=("ADE9653703D4ADE0E997758128555A66D7E1DEC9") # Daniel Scharrer <daniel@constexpr.org>
  19
  20 build() {
  21     cd "$pkgname-$pkgver"
  22
  23     # https://github.com/dscharrer/innoextract/issues/88
  24     cmake . -DCMAKE_INSTALL_PREFIX=/usr -DBoost_NO_BOOST_CMAKE=ON
  25     make
  26 }
  27
  28 package() {
  29     cd "$pkgname-$pkgver"
  30     make DESTDIR="$pkgdir/" install
  31
  32     install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
  33     install -m644  CHANGELOG "$pkgdir/usr/share/doc/$pkgname/CHANGELOG"
  34     install -Dm644 LICENSE   "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  35 }