iverilog/trunk/PKGBUILD

   1 # Maintainer: Alexander F Rødseth <xyproto@archlinux.org>
   2 # Contributor: Jared Casper <jaredcasper@gmail.com>
   3 # Contributor: Paulo Matias <matias archlinux-br org>
   4
   5 pkgname=iverilog
   6 pkgver=12.0
   7 pkgrel=1
   8 pkgdesc='Icarus Verilog compiler and simulation tool'
   9 arch=('x86_64')
  10 url='https://github.com/steveicarus/iverilog'
  11 license=('GPL')
  12 depends=('zlib' 'bzip2')
  13 makedepends=('gperf' 'git')
  14 options=('staticlibs')
  15 source=("git+https://github.com/steveicarus/iverilog#tag=v${pkgver/./_}"
  16         fix-string-literal.patch::https://github.com/steveicarus/iverilog/commit/23e51ef7a8e8e4ba42208936e0a6a25901f58c65.patch)
  17 md5sums=('SKIP'
  18          '35359d78199f3093b99436e1370249b3')
  19
  20 prepare() {
  21   cd "$pkgname"
  22
  23   patch -Np1 < ../fix-string-literal.patch
  24
  25   aclocal
  26   autoconf
  27 }
  28
  29 build() {
  30   cd "$pkgname"
  31
  32   CFLAGS+=' -ffat-lto-objects -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  33
  34   CXXCPP=/usr/bin/cpp ./configure --prefix=/usr
  35   make
  36 }
  37
  38 package() {
  39   make -C "$pkgname" -j1 prefix="$pkgdir/usr" install
  40 }
  41
  42 # vim: ts=2 sw=2 et:
  43 # getver: raw.githubusercontent.com/steveicarus/iverilog/master/scripts/MAKE_RELEASE.sh