jack_mixer/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2
   3 pkgname=jack_mixer
   4 pkgver=17
   5 pkgrel=3
   6 pkgdesc="Jack desktop mixer application"
   7 arch=('x86_64')
   8 url="https://github.com/jack-mixer/jack_mixer"
   9 license=('GPL2')
  10 groups=('pro-audio')
  11 depends=('gcc-libs' 'glibc' 'hicolor-icon-theme' 'python-cairo'
  12 'python-gobject' 'python-xdg')
  13 makedepends=('cython' 'glib2' 'jack2' 'meson' 'python-docutils')
  14 optdepends=('new-session-manager: for session management')
  15 source=("$pkgname-$pkgver.tar.gz::https://github.com/jack-mixer/${pkgname}/archive/release-${pkgver//./-}.tar.gz")
  16 sha512sums=('1ffe39682b40ffca8f4d3e84b13ce1deff77be68f5fe7f37a715d8eebfe7806b909c4d8e4aa178cd6410263df45b855e7db61c7bd068fcae437b7772b215751a')
  17 b2sums=('a6c66f9e68bb9f7b61341b5497eac9966fcdba277fea47b114494f5b93bdcf35020c600b6d732499f9322233f48b8f6c4335ee1a509055a1a63c9072581a59ef')
  18
  19 prepare() {
  20   mv -v "$pkgname-release-${pkgver//./-}" "$pkgname-$pkgver"
  21 }
  22
  23 build() {
  24   cd "$pkgname-$pkgver"
  25   arch-meson --prefix=/usr \
  26              --libdir=lib \
  27              --buildtype=release \
  28              build
  29   ninja -C build
  30 }
  31
  32 check() {
  33   cd "$pkgname-$pkgver"
  34   meson test -C build
  35 }
  36
  37 package() {
  38   depends+=('libglib-2.0.so' 'libjack.so')
  39   cd "$pkgname-$pkgver"
  40   DESTDIR="${pkgdir}" meson install -C build
  41   install -vDm 644 *.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  42 }