jupyter-server/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2
   3 pkgname=jupyter-server
   4 pkgver=2.5.0
   5 pkgrel=3
   6 pkgdesc='Provides the backend for Jupyter web applications like Jupyter notebook, JupyterLab, and Voila'
   7 arch=(any)
   8 url='https://jupyter.org/'
   9 license=(custom)
  10 depends=(python-jupyter_client jupyter-nbformat jupyter-nbconvert python-terminado python-prometheus_client python-traitlets python-tornado
  11          python-jinja python-send2trash python-anyio python-jupyter_packaging python-websocket-client python-requests-unixsocket
  12          python-argon2_cffi python-jupyter-events)
  13 makedepends=(python-build python-installer python-hatch-jupyter-builder)
  14 checkdepends=(python-pytest-tornasync python-pytest-console-scripts python-pytest-timeout python-pytest-jupyter)
  15 optdepends=('jupyter-server-mathjax: to use local MathJax')
  16 source=(https://pypi.io/packages/source/j/${pkgname/-/_}/${pkgname/-/_}-$pkgver.tar.gz)
  17 sha256sums=('9fde612791f716fd34d610cd939704a9639643744751ba66e7ee8fdc9cead07e')
  18
  19 prepare() {
  20   cd ${pkgname/-/_}-$pkgver
  21   sed -e '/jupyter_server_terminals/d' -i pyproject.toml # Prevent cyclic dependencies
  22 }
  23
  24 build() {
  25   cd ${pkgname/-/_}-$pkgver
  26   python -m build --wheel --no-isolation
  27 }
  28
  29 check() {
  30   cd ${pkgname/-/_}-$pkgver
  31 # tests fail on the build server, run them locally
  32 # pytest -v
  33 }
  34
  35 package() {
  36   cd ${pkgname/-/_}-$pkgver
  37   python -m installer --destdir="$pkgdir" dist/*.whl
  38
  39   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
  40 }