kicad-library/repos/community-any/PKGBUILD

   1 # Maintainer: Filipe Laíns <lains@archlinux.org>
   2 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   3 # Contributor: Kyle Keen <keenerd@gmail.com>
   4 # Contributor: Rachel Mant <aur@dragonmux.network>
   5
   6 pkgbase=kicad-library
   7 pkgname=($pkgbase{,-3d})
   8 pkgver=7.0.3
   9 pkgrel=1
  10 pkgdesc='Assorted libraries for KiCad'
  11 arch=('any')
  12 url='http://kicad.org/'
  13 license=('GPL')
  14 makedepends=('git' 'cmake')
  15 options=('!strip')
  16 source=(
  17   'git+https://gitlab.com/kicad/libraries/kicad-packages3D.git#commit=fbe7ce40b9937b20195822aafc9390742089f727'
  18   'git+https://gitlab.com/kicad/libraries/kicad-symbols.git#commit=ceb4d7bdb7a15722c13ac355b8f5c8ca8698a797'
  19   'git+https://gitlab.com/kicad/libraries/kicad-templates.git#commit=867eef383a0f61015cb69677d5c632d78a2ea01a'
  20   'git+https://gitlab.com/kicad/libraries/kicad-footprints.git#commit=62b8ab8b7b0a57b29c6ffaa7a246a671c72fb1b5'
  21 )
  22 md5sums=('SKIP'
  23          'SKIP'
  24          'SKIP'
  25          'SKIP')
  26
  27 build() {
  28   for package in symbols footprints packages3D templates; do
  29      cmake \
  30        -B "build-$package" \
  31        -S "kicad-$package" \
  32        -DCMAKE_INSTALL_PREFIX=/usr
  33
  34      cmake --build "build-$package"
  35    done
  36 }
  37
  38 package_kicad-library() {
  39   pkgdesc="KiCad symbol, footprint and template libraries"
  40
  41   for package in symbols footprints templates; do
  42     DESTDIR="$pkgdir" cmake --install "build-$package"
  43   done
  44 }
  45
  46 package_kicad-library-3d() {
  47   pkgdesc="KiCad 3D model libraries"
  48
  49   DESTDIR="$pkgdir" cmake --install build-packages3D
  50 }
  51
  52 # vim:set ts=2 sw=2 et: