knative-client/repos/community-x86_64/PKGBUILD

   1 # Maintainer : Christian Rebischke <chris.rebischke@archlinux.org>
   2
   3 pkgname=knative-client
   4 _pkgname=client
   5 pkgver=1.10.0
   6 pkgrel=1
   7 pkgdesc="knative client"
   8 arch=('x86_64')
   9 url="https://github.com/knative/client"
  10 license=('Apache')
  11 makedepends=('go')
  12 depends=('glibc')
  13 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/knative/${_pkgname}/archive/refs/tags/knative-v${pkgver}.tar.gz")
  14 sha512sums=('65303d40514dfc62ada69f2687fb1aef69b0caa6da51e66d98ef67a0b0e77c6d2812055da7f8e37678ea85e00df9828c32a8c2c7cfb74db5848b6632eddaf6d8')
  15 b2sums=('9b446e212f8e65fab1fb8d5d85c2dd926406f79cb37c8b9e0a81df4f98a26bd00ae61745e3d032a48994970de5b19af2ec8bafad4aaffdb5ea535730174c70d3')
  16
  17 build() {
  18   cd "client-knative-v${pkgver}/cmd/kn"
  19   export CGO_CPPFLAGS="${CPPFLAGS}"
  20   export CGO_CFLAGS="${CFLAGS}"
  21   export CGO_CXXFLAGS="${CXXFLAGS}"
  22   export CGO_LDFLAGS="${LDFLAGS}"
  23   export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw -ldflags=-linkmode=external"
  24   go build -v
  25 }
  26
  27 check() {
  28   cd "client-knative-v${pkgver}"
  29   go test -v ./...
  30 }
  31
  32 package() {
  33   cd "client-knative-v${pkgver}/cmd/kn"
  34   mkdir -p "${pkgdir}/usr/share/bash-completion/completions"
  35   mkdir -p "${pkgdir}/usr/share/zsh/site-functions"
  36   ./kn completion zsh > "${pkgdir}/usr/share/zsh/site-functions/_kn"
  37   ./kn completion bash > "${pkgdir}/usr/share/bash-completion/completions/kn"
  38   install -Dm755 kn "${pkgdir}/usr/bin/kn"
  39 }