lib32-glib-networking/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: josephgbr <rafael.f.f1@gmail.com>
   3
   4 pkgname=lib32-glib-networking
   5 pkgver=2.76.0
   6 pkgrel=1
   7 pkgdesc="Network extensions for GLib (32-bit)"
   8 url="https://gitlab.gnome.org/GNOME/glib-networking"
   9 arch=(x86_64)
  10 license=(GPL2)
  11 depends=(
  12   glib-networking
  13   lib32-glib2
  14   lib32-gnutls
  15   lib32-libproxy
  16 )
  17 makedepends=(
  18   git
  19   meson
  20 )
  21 checkdepends=(ca-certificates)
  22 _commit=eab226398f9872c381033f7cb3af43dcb66600f4  # tags/2.76.0^0
  23 source=("git+https://gitlab.gnome.org/GNOME/glib-networking.git#commit=${_commit}")
  24 sha256sums=('SKIP')
  25
  26 pkgver() {
  27   cd glib-networking
  28
  29   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  30 }
  31
  32 build() {
  33   export CC='gcc -m32'
  34   export CXX='g++ -m32'
  35   export PKG_CONFIG=i686-pc-linux-gnu-pkg-config
  36
  37   arch-meson glib-networking build --libdir=/usr/lib32
  38   meson compile -C build
  39 }
  40
  41 check() {
  42   meson test -C build --print-errorlogs
  43 }
  44
  45 package() {
  46   meson install -C build --destdir "${pkgdir}"
  47   rm -r "${pkgdir}"/usr/{lib,share}
  48 }
  49
  50 # vim:set sw=2 sts=-1 et: