lib32-libxcrypt/trunk/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2
   3 pkgbase=lib32-libxcrypt
   4 pkgname=(lib32-libxcrypt lib32-libxcrypt-compat)
   5 pkgver=4.4.33
   6 pkgrel=1
   7 pkgdesc='Modern library for one-way hashing of passwords (32-bit)'
   8 arch=('x86_64')
   9 url='https://github.com/besser82/libxcrypt/'
  10 license=('GPL')
  11 depends=('lib32-glibc' 'libxcrypt')
  12 makedepends=('gcc-multilib')
  13 validpgpkeys=('678CE3FEE430311596DB8C16F52E98007594C21D') # Björn 'besser82' Esser
  14 source=("${url}/releases/download/v${pkgver}/libxcrypt-${pkgver}.tar.xz"{,.asc})
  15 sha256sums=('e87acf9c652c573a4713d5582159f98f305d56ed5f754ce64f57d4194d6b3a6f'
  16             'SKIP')
  17
  18 build() {
  19   export CC="gcc -m32"
  20   export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
  21
  22   mkdir build-libxcrypt build-libxcrypt-compat
  23   cd "${srcdir}/build-libxcrypt/"
  24   "${srcdir}/libxcrypt-${pkgver}"/configure \
  25     --prefix=/usr \
  26     --libdir=/usr/lib32 \
  27     --libexecdir=/usr/lib32 \
  28     --disable-static \
  29     --enable-hashes=strong,glibc \
  30     --enable-obsolete-api=no \
  31     --disable-failure-tokens
  32   make
  33
  34   cd "${srcdir}/build-libxcrypt-compat/"
  35   "${srcdir}/libxcrypt-${pkgver}"/configure \
  36     --prefix=/usr \
  37     --libdir=/usr/lib32 \
  38     --libexecdir=/usr/lib32 \
  39     --disable-static \
  40     --enable-hashes=strong,glibc \
  41     --enable-obsolete-api=glibc \
  42     --disable-failure-tokens
  43   make
  44 }
  45
  46 package_lib32-libxcrypt() {
  47   cd build-libxcrypt/
  48
  49   make DESTDIR="${pkgdir}" install
  50
  51   rm -rf "${pkgdir}"/usr/{bin,include,share}
  52 }
  53
  54 package_lib32-libxcrypt-compat() {
  55   pkgdesc='Modern library for one-way hashing of passwords - legacy API functions (32bit)'
  56   depends=('lib32-libxcrypt')
  57
  58   cd build-libxcrypt-compat/
  59   make DESTDIR="${pkgdir}" install
  60   rm -rf "${pkgdir}"/usr/{include,lib32/{lib*.so,pkgconfig},share}
  61 }