libbobcat/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Konstantin Gizdov <arch at kge dot pw>
   2 # Contributor: Kevin Brodsky <corax26 at gmail dot com>
   3 # Contributor: Anton Jongsma <anton@felrood.nl>
   4
   5 _pkgname=bobcat
   6 pkgname="lib${_pkgname}"
   7 pkgver=6.02.02
   8 pkgrel=1
   9 pkgdesc="Bobcat (Brokken's Own Base Classes And Templates) library"
  10 arch=('x86_64')
  11 url="https://fbb-git.gitlab.io/bobcat/"
  12 license=('GPL')
  13 depends=('openssl' 'libx11' 'readline')
  14 makedepends=('icmake>=9.03.01' 'libmilter' 'yodl')
  15 source=("https://gitlab.com/fbb-git/${_pkgname}/-/archive/${pkgver}/${_pkgname}-${pkgver}.tar.gz")
  16 b2sums=('4908fef5685e5402795000fafee7fcb3c42c4cf94571121df7e1afd977961f3d3036393f7140867abb9a019713ddb886053e4900172ef1072944b77444d2b11d')
  17
  18 build() {
  19   cd "${srcdir}/${_pkgname}-${pkgver}/${_pkgname}"
  20
  21   # Since makepkg always defines CXXFLAGS, it overrides the default value
  22   # defined in the build system, which is problematic because it needs a
  23   # specific C++ version. Add it back here.
  24   export CXXFLAGS="${CXXFLAGS} -std=c++20"
  25
  26   ./build libraries all
  27   ./build man
  28 }
  29
  30 package() {
  31   cd "${srcdir}/${_pkgname}-${pkgver}/${_pkgname}"
  32
  33   # Since 4.01.02, first argument to install is <what to install> (x = all),
  34   # and second is the base directory (absolute path, unlike 4.01.00)
  35   ./build install x "${pkgdir}"
  36
  37   # fix paths
  38   ln -s /usr/share/doc/libbobcat5-dev "${pkgdir}/usr/share/doc/${pkgname}"
  39 }