libev/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Andrea Scarpino <andrea@archlinux.org>
   2 # Contributor: Allan McRae <allan@archlinux.org>
   3 # Contributor: Thomas Haider <t.haider@vcnc.org>
   4
   5 pkgname=libev
   6 pkgver=4.33
   7 pkgrel=2
   8 pkgdesc="A full-featured and high-performance event loop"
   9 arch=('x86_64')
  10 url="https://software.schmorp.de/pkg/libev.html"
  11 license=('BSD')
  12 depends=('glibc')
  13 source=(http://dist.schmorp.de/${pkgname}/${pkgname}-${pkgver}.tar.gz)
  14 sha512sums=('c662a65360115e0b2598e3e8824cf7b33360c43a96ac9233f6b6ea2873a10102551773cad0e89e738541e75af9fd4f3e3c11cd2f251c5703aa24f193128b896b')
  15 b2sums=('8a6cae25ffde10b24a5bbf084f6a8559af326b37acdbdf47dda34b7f0c7955f3ebd26958594444a574cfa3e2b4011e4be93ad2bd994ffd4c094bf36620e67ba5')
  16
  17 build() {
  18   cd ${pkgname}-${pkgver}
  19
  20   ./configure --prefix=/usr
  21
  22   make
  23 }
  24
  25 check() {
  26   cd ${pkgname}-${pkgver}
  27
  28   make check
  29 }
  30
  31 package() {
  32   cd ${pkgname}-${pkgver}
  33
  34   make DESTDIR="${pkgdir}" install
  35
  36   # fix conflict with libevent
  37   rm "${pkgdir}"/usr/include/event.h
  38
  39   # license
  40   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  41 }