liblrdf/trunk/PKGBUILD

   1 # Maintainer: David Runge <dave@sleepmap.de>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3
   4 pkgname=liblrdf
   5 pkgver=0.6.1
   6 pkgrel=4
   7 pkgdesc="A library for the manipulation of RDF file in LADSPA plugins"
   8 arch=('x86_64')
   9 url="https://github.com/swh/LRDF"
  10 depends=('raptor')
  11 makedepends=('ladspa')
  12 provides=('liblrdf.so')
  13 license=('GPL2')
  14 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/swh/LRDF/archive/v${pkgver}.tar.gz")
  15 sha512sums=('7732813eec704aef984d056de254e4fa049fdd0a7444b6a88f75f012afe9c587cbd1295f027c77361fa42bc097cdce9d9cabdba6b86e99a3c14805d84258df1c')
  16
  17 prepare() {
  18   mv -v "LRDF-${pkgver}" "${pkgname}-${pkgver}"
  19   cd "${pkgname}-${pkgver}"
  20   autoreconf -vfi
  21 }
  22
  23 build() {
  24   cd "${pkgname}-${pkgver}"
  25   # raptor.h changed location
  26   export CXXFLAGS="$(pkg-config --cflags raptor2) ${CXXFLAGS}"
  27   ./configure --prefix=/usr
  28   make
  29 }
  30
  31 package() {
  32   cd "${pkgname}-${pkgver}"
  33   make DESTDIR="${pkgdir}" install
  34   install -vDm 644 {AUTHORS,ChangeLog,NEWS,README} \
  35     -t "${pkgdir}/usr/share/doc/${pkgname}"
  36 }