libtpms/trunk/PKGBUILD

   1 # Maintainer: Jonas Witschel <diabonas@archlinux.org>
   2 pkgname=libtpms
   3 pkgver=0.9.6
   4 _tag=fccd9f0ec5febf75ccec2742e75889cdfa329e53 # git rev-parse "v$pkgver"
   5 pkgrel=1
   6 pkgdesc='Library providing a software emulation of a Trusted Platform Module (TPM 1.2 and TPM 2.0)'
   7 arch=('x86_64')
   8 url='https://github.com/stefanberger/libtpms'
   9 license=('BSD')
  10 depends=('openssl')
  11 makedepends=('git')
  12 source=("git+$url.git?signed#tag=$_tag")
  13 sha512sums=('SKIP')
  14 validpgpkeys=('B818B9CADF9089C2D5CEC66B75AD65802A0B4211') # Stefan Berger <stefanb@linux.vnet.ibm.com>
  15
  16 pkgver() {
  17         cd "$pkgname"
  18         git describe | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g'
  19 }
  20
  21 prepare() {
  22         cd "$pkgname"
  23         autoreconf --install --force
  24 }
  25
  26 build() {
  27         cd "$pkgname"
  28         ./configure --prefix=/usr --with-openssl --with-tpm2
  29         make
  30 }
  31
  32 check() {
  33         cd "$pkgname"
  34         make check
  35 }
  36
  37 package() {
  38         cd "$pkgname"
  39         make DESTDIR="$pkgdir" install
  40         install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  41 }