libva1-intel-driver/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   4
   5 pkgname=libva1-intel-driver
   6 pkgver=1.8.3
   7 pkgrel=2
   8 pkgdesc='VA-API implementation for Intel G45 and HD Graphics family'
   9 arch=('x86_64')
  10 url='https://01.org/linuxmedia/vaapi'
  11 license=('MIT')
  12 depends=('libva1' 'libdrm')
  13 makedepends=('git')
  14 source=("git+https://github.com/intel/intel-vaapi-driver.git#tag=${pkgver}")
  15 sha256sums=('SKIP')
  16
  17 prepare() {
  18   cd intel-vaapi-driver
  19
  20   # Only relevant if intel-gpu-tools is installed,
  21   # since then the shaders will be recompiled
  22   sed -i '1s/python$/&2/' src/shaders/gpp.py
  23
  24   NOCONFIGURE=1 ./autogen.sh
  25 }
  26
  27 build() {
  28   cd intel-vaapi-driver
  29
  30   CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  31
  32   export PKG_CONFIG_PATH='/usr/lib/libva1/pkgconfig'
  33
  34   ./configure \
  35     --prefix='/usr' \
  36     --libdir='/usr/lib/libva1'
  37   make
  38 }
  39
  40 package() {
  41   make DESTDIR="${pkgdir}" -C intel-vaapi-driver install
  42   install -Dm 644 intel-vaapi-driver/COPYING -t "${pkgdir}"/usr/share/licenses/libva1-intel-driver
  43 }
  44
  45 # vim: ts=2 sw=2 et: