lsb-release/trunk/PKGBUILD

   1 # Maintainer: Jonas Witschel <diabonas@archlinux.org>
   2 # Contributor: Sven-Hendrik Haase <sh@lutzhaase.com>
   3 # Contributor: Malte Rabenseifner <malte@zearan.de>
   4 # Contributor: John Gerritse <reaphsharc@gmail.com>
   5
   6 pkgname=lsb-release
   7 pkgver=2.0.r48.3cf5103
   8 _commit=3cf51039933d03ef15388b75d30baa5d5e09a1a0
   9 pkgrel=1
  10 pkgdesc="LSB version query program"
  11 arch=('any')
  12 url="https://refspecs.linuxfoundation.org/lsb.shtml"
  13 license=('GPL')
  14 depends=('sh')
  15 makedepends=('git')
  16 source=("git+https://github.com/LinuxStandardBase/lsb-samples.git#commit=$_commit"
  17         'lsb-release'
  18         'lsb_release_description.patch'
  19         'lsb_release_make_man_page_reproducible.patch')
  20 sha512sums=('SKIP'
  21             'c4fb9d1026b6cc362b95d8b6662709ec18c0c8cb642d3a811d75bbb0e2fda93e1281accce40b7e7d5cde162144486a29d4c34ccbffcdd8f18e0ff51aef83db97'
  22             '145ef64f90f5e6cc59075679e640cf7c1ad02617c12eff17f10b05c1cc219591fdba1b27be2b2c8480742aed24ce81d6a7badcbaca6772faea4ebc6a55695b62'
  23             'ab64a1d236d00a30a48e3af2c5bdfa0aad0183ebe0df4f2b0c6af58530c2a1fdac1b0a5cdd8a1800d5f8405f44562603cddf28eb318b5badaabd49a82e0b7e83')
  24
  25 pkgver() {
  26         cd lsb-samples/lsb_release/src
  27         printf "%s.r%s.%s" "$(grep -Po 'SCRIPTVERSION="\K[^"]*' lsb_release)" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  28 }
  29
  30 prepare() {
  31         cd lsb-samples/lsb_release/src
  32         patch -Np0 -i "$srcdir/lsb_release_description.patch"
  33         patch -Np1 -i "$srcdir/lsb_release_make_man_page_reproducible.patch"
  34 }
  35
  36 build() {
  37         cd lsb-samples/lsb_release/src
  38         make
  39 }
  40
  41 package() {
  42         cd lsb-samples/lsb_release/src
  43         install -Dm644 lsb_release.1.gz -t "$pkgdir/usr/share/man/man1"
  44         install -Dm755 lsb_release -t "$pkgdir/usr/bin"
  45         install -Dm644 "$srcdir/lsb-release" -t "$pkgdir/etc"
  46 }