magnum-plugins/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
   2 # Contributor: Mosra <mosra@centrum.cz>
   3
   4 pkgname=magnum-plugins
   5 pkgver=2020.06
   6 _basis_pkgver=2f43afcc97d0a5dafdb73b4e24e123cf9687a418
   7 _meshoptimizer_pkgver=0.14
   8 pkgrel=3
   9 pkgdesc='Plugins for the Magnum C++11/C++14 graphics engine'
  10 arch=(x86_64)
  11 url='https://magnum.graphics'
  12 license=(MIT)
  13 depends=(assimp devil faad2 freetype2 libjpeg libpng magnum)
  14 makedepends=(cmake git glfw ninja)
  15 source=("git+https://github.com/mosra/magnum-plugins#commit=b0f2818b781eb0fb6a8a76095a6529fc85d442f3"
  16         "basis_universal.tar.gz::https://github.com/BinomialLLC/basis_universal/archive/${_basis_pkgver}.tar.gz"
  17         "meshoptimizer.tar.gz::https://github.com/zeux/meshoptimizer/archive/v${_meshoptimizer_pkgver}.tar.gz")
  18 sha256sums=('SKIP'
  19             'f983ab5bfc5c32474914a87d9ca572c7fb970bf96f7bc68385c08772f633639f'
  20             '5a6e429ecf72325131b439a46297a690f0cab833c7563efdadab26c0a6cf8490')
  21
  22 build() {
  23   mkdir -p build
  24   cd build
  25
  26   # Bundle Basis Universal and meshoptimizer
  27   ln -sf "$srcdir"/basis_universal-${_basis_pkgver}/ "$srcdir/${pkgname%-git}/src/external/basis-universal"
  28   ln -sf "$srcdir"/meshoptimizer-${_meshoptimizer_pkgver}/ "$srcdir/${pkgname%-git}/src/external/meshoptimizer"
  29
  30   cmake "$srcdir/magnum-plugins" \
  31     -DCMAKE_BUILD_TYPE=Release \
  32     -DCMAKE_INSTALL_PREFIX=/usr \
  33     -DWITH_ASSIMPIMPORTER=ON \
  34     -DWITH_BASISIMAGECONVERTER=ON \
  35     -DWITH_BASISIMPORTER=ON \
  36     -DWITH_DDSIMPORTER=ON \
  37     -DWITH_DEVILIMAGEIMPORTER=ON \
  38     -DWITH_DRFLACAUDIOIMPORTER=ON \
  39     -DWITH_DRMP3AUDIOIMPORTER=ON \
  40     -DWITH_DRWAVAUDIOIMPORTER=ON \
  41     -DWITH_FAAD2AUDIOIMPORTER=ON \
  42     -DWITH_FREETYPEFONT=ON \
  43     -DWITH_ICOIMPORTER=ON \
  44     -DWITH_JPEGIMAGECONVERTER=ON \
  45     -DWITH_JPEGIMPORTER=ON \
  46     -DWITH_MESHOPTIMIZERSCENECONVERTER=ON \
  47     -DWITH_MINIEXRIMAGECONVERTER=ON \
  48     -DWITH_OPENGEXIMPORTER=ON \
  49     -DWITH_PNGIMAGECONVERTER=ON \
  50     -DWITH_PNGIMPORTER=ON \
  51     -DWITH_PRIMITIVEIMPORTER=ON \
  52     -DWITH_STANFORDIMPORTER=ON \
  53     -DWITH_STANFORDSCENECONVERTER=ON \
  54     -DWITH_STBIMAGECONVERTER=ON \
  55     -DWITH_STBIMAGEIMPORTER=ON \
  56     -DWITH_STBTRUETYPEFONT=ON \
  57     -DWITH_STBVORBISAUDIOIMPORTER=ON \
  58     -DWITH_STLIMPORTER=ON \
  59     -DWITH_TINYGLTFIMPORTER=ON \
  60     -GNinja
  61   ninja
  62 }
  63
  64 package() {
  65   DESTDIR="$pkgdir" ninja -C build install
  66   install -Dm644 $pkgname/COPYING \
  67     "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  68 }
  69
  70 # getver: github.com/mosra/magnum-plugins/releases/latest
  71 # vim: ts=2 sw=2 et: