mc/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Alad Wenter <alad@archlinux.org>
   2 # Maintainer: schuay <jakob.gruber@gmail.com>
   3 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   4
   5 pkgname=mc
   6 pkgver=4.8.27
   7 pkgrel=1
   8 pkgdesc="A file manager that emulates Norton Commander"
   9 arch=('x86_64')
  10 url="https://midnight-commander.org/"
  11 license=('GPL')
  12 depends=('e2fsprogs' 'glib2' 'gpm' 'libssh2' 'slang' 'which')
  13 makedepends=('libxt' 'libx11' 'unzip')
  14 optdepends=('aspell: spelling corrections'
  15             'cabextract: ucab extfs'
  16             'cdparanoia: audio extfs'
  17             'cdrkit: iso9660 extfs'
  18             'cvs: CVS support'
  19             'gawk: hp48+ extfs'
  20             'mtools: a+ extfs'
  21             'p7zip: support for 7zip archives'
  22             'perl: needed by several extfs scripts'
  23             'python: to access uc1541 or s3 storage'
  24             'python-boto: s3+ extfs'
  25             'python-pytz: s3+ extfs'
  26             'samba: VFS support'
  27             'unace: uace extfs'
  28             'unarj: uarj extfs'
  29             'unrar: urar extfs'
  30             'unzip: open zip archives'
  31             'zip: uzip extfs')
  32 backup=('etc/mc/edit.indent.rc'
  33         'etc/mc/filehighlight.ini'
  34         'etc/mc/mc.ext'
  35         'etc/mc/mc.keymap'
  36         'etc/mc/mc.menu'
  37         'etc/mc/mcedit.menu'
  38         'etc/mc/sfs.ini')
  39 options=('!emptydirs')
  40 source=("http://ftp.midnight-commander.org/${pkgname}-${pkgver}.tar.xz"
  41         "mc-mksh-subshell-v2.patch"
  42         "mc-python3.patch")
  43 sha256sums=('31be59225ffa9920816e9a8b3be0ab225a16d19e4faf46890f25bdffa02a4ff4'
  44             '5147afa3f9dfc00d8b7b36bbb144bcdb78d86301a0f8196686262a9eee41fb96'
  45             '10ab8b8c03770f8fe51f0bdbf0d66a44313bf2eed687cf769397909c07d8e8d5')
  46
  47 prepare() {
  48   cd ${pkgname}-${pkgver}
  49   # patch -p1 < "$srcdir"/mc-mksh-subshell-v2.patch
  50   patch -p1 < "$srcdir"/mc-python3.patch
  51 }
  52
  53 build() {
  54   cd ${pkgname}-${pkgver}
  55   ./configure \
  56       --prefix=/usr \
  57       --libexecdir=/usr/lib \
  58       --sysconfdir=/etc \
  59       --enable-vfs-smb \
  60       --with-screen=slang \
  61       --with-x
  62   make
  63 }
  64
  65 package() {
  66   cd ${pkgname}-${pkgver}
  67   make DESTDIR="${pkgdir}" install
  68
  69   # Replace mc.keymap symlink with target file to fix backup mechanism (FS#50889).
  70   rm "${pkgdir}"/etc/mc/mc.keymap && cp "${pkgdir}"/etc/mc/mc{.default,}.keymap
  71 }