miniupnpc/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Timothy Redaelli <timothy.redaelli@gmail.com>
   3 # Contributor: Florian Loitsch <archlinux@florian.loitsch.com>
   4
   5 pkgbase=miniupnpc
   6 pkgname=(miniupnpc python-miniupnpc)
   7 pkgver=2.2.4
   8 pkgrel=2
   9 pkgdesc='Small UPnP client library/tool to access Internet Gateway Devices'
  10 url='https://miniupnp.tuxfamily.org/'
  11 arch=('x86_64')
  12 license=('BSD')
  13 makedepends=('sh' 'glibc' 'lsb-release' 'python' 'python-setuptools')
  14 source=(https://miniupnp.tuxfamily.org/files/${pkgname}-${pkgver}.tar.gz{,.sig})
  15 sha512sums=('f6515bda86405114016474fef6332c0c09a56b9293cf4391113f549444bab67e7d031af7b94dacff5e7c96d6508527204498c00fb67d6067685ef606b2152595'
  16             'SKIP')
  17 b2sums=('ebfea3fe978280825b7beefb8fe799685a72b0a74c589f5f55c7fde3d8c0d4bbb3d50fa0ff3aed554fa1e24ada0a1ab578328373f0295020415998fe35cde0a0'
  18         'SKIP')
  19 validpgpkeys=(
  20   '751E9FF6944A3B36A5432216DB511043A31ACAAF' # miniupnp (miniupnp !) <miniupnp@free.fr>
  21 )
  22
  23 build() {
  24   cd ${pkgname}-${pkgver}
  25   make
  26   python setup.py build
  27 }
  28
  29 check() {
  30   cd ${pkgname}-${pkgver}
  31   make test
  32 }
  33
  34 package_miniupnpc() {
  35   depends=(sh glibc)
  36   provides=(libminiupnpc.so)
  37
  38   cd ${pkgname}-${pkgver}
  39   make DESTDIR="${pkgdir}" install
  40   install -Dm 644 man3/miniupnpc.3 -t "${pkgdir}/usr/share/man/man3"
  41   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  42 }
  43
  44 package_python-miniupnpc() {
  45   pkgdesc='Python bindings for miniupnpc'
  46   depends=(python glibc)
  47
  48   cd ${pkgbase}-${pkgver}
  49   python setup.py install --optimize=1 --skip-build --root="$pkgdir"
  50   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  51 }
  52
  53 # vim: ts=2 sw=2 et: